Search This Blog

Menampilkan File Select Dialog Box

Pada aplikasi Microsoft Access mungkin saja kita perlu untuk melakukan browse ke hardisk untuk mencari file untuk proses tertentu, misalnya mengexport data ke file lain.
Untuk mempermudah pencarian file, kita dapat memanfaatkan Common Dialog DLL yang ada pada Windows System. Fungsi DLL yang akan kita manfaatkan adalah untuk menampilkan file select dialog box.
Untuk menampilkan file select dialog box pada Access kita harus memanggil fungsi tersebut ke dalam aplikasi Microsoft Access yang kita bangun.

Berikut adalah contoh gambar File Select dialog box:


Cara menggunakan fungsi Select File dialog box ini adalah sbb:

1. Insertkan code program ini ke dalam module di file Microsoft Access yang anda buat.
Private Declare Function GetOpenFileName Lib "comdlg32.dll" Alias _
"GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long

Private Type OPENFILENAME
lStructSize As Long
hwndOwner As Long
hInstance As Long
lpstrFilter As String
lpstrCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
lpstrFile As String
nMaxFile As Long
lpstrFileTitle As String
nMaxFileTitle As Long
lpstrInitialDir As String
lpstrTitle As String
flags As Long
nFileOffset As Integer
nFileExtension As Integer
lpstrDefExt As String
lCustData As Long
lpfnHook As Long
lpTemplateName As String
End Type

Function CariFile(strform As Form) As String
Dim OpenFile As OPENFILENAME
Dim lReturn As Long
Dim sFilter As String
OpenFile.lStructSize = Len(OpenFile)
OpenFile.hwndOwner = strform.Hwnd
sFilter = "All Files (*.*)" & Chr(0) & "*.*" & Chr(0) & _
"JPEG Files (*.JPG)" & Chr(0) & "*.JPG" & Chr(0)
OpenFile.lpstrFilter = sFilter
OpenFile.nFilterIndex = 1
OpenFile.lpstrFile = String(257, 0)
OpenFile.nMaxFile = Len(OpenFile.lpstrFile) - 1
OpenFile.lpstrFileTitle = OpenFile.lpstrFile
OpenFile.nMaxFileTitle = OpenFile.nMaxFile
OpenFile.lpstrInitialDir = "C:\"
OpenFile.lpstrTitle = "Select a file using the Common Dialog DLL"
OpenFile.flags = 0
lReturn = GetOpenFileName(OpenFile)
If lReturn = 0 Then
    MsgBox "A file was not selected!", vbInformation, _
      "Select a file using the Common Dialog DLL"
 Else
    CariFile = Trim(Left(OpenFile.lpstrFile, InStr(1, OpenFile.lpstrFile, vbNullChar) - 1))
 End If
End Function


2. Memanggil fungsi CariFile()

Sebagai contoh buatlah 1 buah form dengan satu buah textbox untuk menyimpan variable nama file dan 1 buah tombol untuk melakukan proses browse pada harddisk.


- Property name textbox pada form ini adalah NAMA_FILE
- Property name command buttonnya adalah cmdBrowse

Pada even OnClick di tombol cmdBrowse pada form ini kita panggil fungsi CariFile().
Private Sub cmdBrowse_Click()
Me.NAMA_FILE.Value = CariFile(Me)
End Sub

Jika form ini dijalankan dan anda klik pada tombol cmdBrowse maka akan muncul windows dialog box file select dan user dapat membrowse hardisk untuk mencari nama file dan nama folder yang akan disimpan datanya pada texbox NAMA_FILE pada form ini.

Download contoh demo program Access select file dialog box di sini.

Selamat mencoba…

2 comments:

Anonymous said...

Terima kasih sebelumnya atas informasi yang sangat berguna bagi saya dalam mempelajari pemrograman di Ms Access. Yang ingin saya tanyakan bagaimana cara mendapatkan path/folder untuk menyimpan file/hasil TransferSpreedsheet. contoh di atas kan untuk membuka file, bagaimana kalau untuk menyimpan file. terima kasih.

Sukadana said...

Minta tolong donk.. Gimana caranya cetak buku tabungan dimana barisnya kan disesuaikan. yang tercetak hanya record yang kita input baru saja atau record yang belum pernah di print dan spasi cetak atau urutan barisnya kita yang tentukan..

Tolooong ya..

Txz